DrugWar for Sharp EL-9600

I haven't finished converting the text version, below, to a readable format yet, but the computer link version is available for those of you with one.

Generally special characters (not obvious how to enter or not representable in plain text) are enclosed by two @ characters.

SYMBOL EXPLANATION AND KEY LOCATION:
@a@     means   lowercase a (press [VARS] [H] [ENTER] [B] [2])
@d@     means   lowercase d (press [VARS] [H] [ENTER] [B] [5])
@e@     means   lowercase e (press [VARS] [H] [ENTER] [B] [6])
@n@     means   lowercase n (press [VARS] [H] [ENTER] [A] [1])
@r@     means   lowercase r (press [VARS] [H] [ENTER] [B] [7])
s       means   lowercase s (press [VARS] [H] [ENTER] [B] [2])
@t@     means   lowercase t (press [VARS] [H] [ENTER] [D] [3])
@w@     means   lowercase w (press [2ndF] [9])
@sto@   means   Store (press [STO])
@EE@    means   Exponent (press [2ndF] [,])
@not_=@ means   Not equal to  (press [MATH] [F] [2])
@-@     means   Unary negation (press [(-)] (the key below the 3 key))
@>=@    means   Greater than or equal to (press [MATH] [F] [4])
@<=@    means   Greater than or equal to (press [MATH] [F] [6])

ClrT
Print "       DRUGWAR
Print "     JASSIMO 1997
Print ""
Print "   CONVERTED FOR THE       SHARP EL-9600
Print " BY J@a@M@e@s An@d@@r@@e@w@a@@r@tH@a@
Print ""
Print "   VERSION 1.1 1998
Wait 7
{6,2}@sto@dim(mat B)
fill(0,mat B)
2000@sto@M
5000@sto@D
0@sto@B
100@sto@T
100@sto@F
0@sto@G
0@sto@A
1@sto@Y
3@sto@P
ClrT
Print "HIGHSCORE:
Print K
Print "INSTRUCTIONS
Print "1) YES  2) NO
Input C
If C=1Goto INSTRUC
Label NEWDAY
random @sto@C
int (12@EE@3random )+16@EE@3@sto@mat B(1,1)
int (7@EE@3random )+5@EE@3@sto@mat B(2,1)
int (3400random )+1@EE@3@sto@mat B(3,1)
int (420random )+330@sto@mat B(4,1)
int (150random )+70@sto@mat B(5,1)
int (40random )+10@sto@mat B(6,1)
int (20random +1)@sto@E
ClrT
If E>1Goto CHWEED
Print "RIVAL DEALERS ARE     SELLING CHEAP DEXIES!!
2@sto@mat B(6,1)
Wait 
Goto MENU
Label CHWEED
If E>2Goto CHHEROIN
Print "WEED PRICES HAVE      BOTTOMED OUT!!
122@sto@mat B(4,1)
Wait 
Goto MENU
Label CHHEROIN
If E>3Goto EXHEROIN
Print "PIGS ARE SELLING CHEAPHEROIN FROM LAST      WEEK'S RAID
int (1150random )+850@sto@mat B(2,1)
Wait 
Goto MENU
Label EXHEROIN
If E>5Goto EXCOKE
Print "ADDICTS ARE BUYING    HEROIN AT OUTRAGEOUS  PRICES!!
int (25@EE@3random )+18@EE@3@sto@mat B(2,1)
Wait 
Goto MENU
Label EXCOKE
If E>7Goto MUGGED
Print "PIGS MADE A BIG COKE  BUST. PRICES ARE      OUTRAGEUS!!
int (6@EE@4random )+8@EE@4@sto@mat B(1,1)
Wait 
Goto MENU
Label MUGGED
If E>8Goto NEWCOAT
Print "YOU WERE MUGGED IN THESUBWAY!!
int (G/(G+1)+1.6)@sto@C
int (CM/3)@sto@M
Wait 
Goto MENU
Label NEWCOAT
If E>9Goto DIE
If M<300Goto MENU
Print "WILL YOU BUY A NEW    TRENCHCOAT WITH MORE  POCKETS FOR 200 BUCKS
Input C
If C@not_=@1Goto MENU
T+100@sto@T
Gosub CALCFREE
M-200@sto@M
Goto MENU
Label DIE
If E>10Goto GUN
Print "THERE IS SOME WEED    HERE THAT SMELLS LIKE GOOD STUFF...
Print "WILL YOU SMOKE IT
Input C
If C@not_=@1Goto MENU
Print "YOU HALLUCINATE ON THEWILDEST TRIP OF YOUR  LIFE. YOU STUMBLE ONTO"
Print "THE TRACKS AND GET    CREAMED BY A TRAIN!!"
Wait 
Goto END
Label GUN
If E>12Goto FOUND
If M<500Goto MENU
If F<5Goto MENU
Print "WILL YOU BUY A GUN FOR400 BUCKS
Input C
If C@not_=@1Goto MENU
G+1@sto@G
M-400@sto@M
T-5@sto@T
Gosub CALCFREE
Goto MENU
Label FOUND
If E>13Goto CHACID
If F<7Goto MENU
int (7random )@sto@C
Print "YOU FOUND
Print C
int (6random )+1@sto@X
If X=1Goto FCOKE
If X=2Goto FHEROIN
If X=3Goto FACID
If X=4Goto FWEED
If X=5Goto FSPEED
Print "UNITS OF DEXIES
Goto FDEAD
Label FCOKE
Print "UNITS OF COCAINE
Goto FDEAD
Label FHEROIN
Print "UNITS OF HEROIN
Goto FDEAD
Label FACID
Print "UNITS OF ACID
Goto FDEAD
Label FWEED
Print "UNITS OF WEED
Goto FDEAD
Label FSPEED
Print "UNITS OF SPEED
Label FDEAD
Print "ON A DEAD DUCK IN THE SUBWAY!!
mat B(X,2)+C@sto@mat B(X,2)
Gosub CALCFREE
Wait 
Goto MENU
Label CHACID
If E>14Goto PIGS
Print "THE MARKET HAS BEEN   FLOODED WITH CHEAP    HOME-MADE ACID!!
int (550random )+250@sto@mat B(3,1)
Wait 
Goto MENU
Label PIGS
If E>17Goto MENU
If T-F<50Goto MENU
int ((E-13)/3)+E-14@sto@I
Print "OFFICER HARDASS AND
Print I
Print "OF HIS DEPUTIES ARE   AFTER YOU!!
Wait 
Label CHASE
ClrT
Print "BEING CHASED!!
Print "1) VIEW GUNS
Print "2) VIEW DAMAGE
Print "3) NUMBER OF PIGS
Print "4) RUN  5) FIGHT
Input C
ClrT
If C=2Goto VDAMAGE
If C=3Goto VPIGS
If C=4Goto RUN
If C=5Goto FIGHT
If C<1Goto CHASE
If C>5Goto CHASE
Print "YOU HAVE
Print G
Print "GUNS
Wait 
Goto CHASE
Label VDAMAGE
Print "YOUR DAMAGE IS
Print A
Print "30 DAMAGE AND YOU DIE!
Wait 
Goto CHASE
Label VPIGS
Print "THERE ARE
Print I+1
Print "PIGS STILL CHASING YOU
Wait 
Goto CHASE
Label RUN
int (2random )@sto@X
If X=1Goto CANTSHAKE
Print "YOU LOST THEM IN AN   ALLEY!!
A+1@sto@A
Wait 
If A=31Goto END
Goto NEWDAY
Label CANTSHAKE
Print "YOU CAN'T SHAKE THEM!!
Wait 
Goto THEYSHOOT
Label FIGHT
If G@not_=@0Goto SHOOT
Print "YOU DON'T HAVE ANY    GUNS! YOU'LL HAVE TO  RUN!
Wait 
Goto CHASE
Label SHOOT
int (2random )@sto@X
If X=0Goto MISS
Print "YOU KILLED ONE!!
I-1@sto@I
Wait 
If I=@-@1Goto ALLDEAD
Goto THEYSHOOT
Label MISS
Print "YOU MISSED!!!
Wait 
Label THEYSHOOT
Print "THEY ARE FIRING AT YOU
int (2random )@sto@X
If X=0Goto THEYMISS
Print "YOU'VE BEEN HIT!
A+3@sto@A
Wait 
Print "YOU'VE BEEN KILLED!!
If A@>=@30Goto END
ClrT
Goto CHASE
Label THEYMISS
Print "THEY MISSED!!
Wait 
Goto CHASE
Label ALLDEAD
ClrT
Print "YOU KILLED ALL OF THEM
Wait 
int (1250random )+750@sto@X
M+X@sto@M
Print "YOU FOUND
Print X
Print "DOLLARS ON OFFICER    HARDASS' CARCASS!!
Wait 
If A=0Goto MENU
Print "YOU ARE HURT!
If M>1200Goto FIXUP
Print "BUT YOU CAN'T AFFORD  MEDICAL HELP...
Wait 
Goto MENU
Label FIXUP
Print "WILL YOU PAY 1000     DOLLARS FOR A DOCTOR  TO SEW YOU UP
Input C
If C@not_=@1Goto MENU
M-1000@sto@M
0@sto@A
Label MENU
ClrT
Print "1) SEE PRICES
Print "2) TRENCHCOAT
Print "3) BUY  4) SELL
Print "5) GO   6) BANK
Print "7) LOAN SHARK
Input C
ClrT
Print "DAY:
Print Y
Wait 
If C=2Goto TRENCHCOAT
If C=3Goto BUY
If C=4Goto SELL
If C=5Goto GO
If C=6Goto BANK
If C=7Goto LOAN
Print "COCAINE:
Print mat B(1,1)
Print "HEROIN:
Print mat B(2,1)
Print "ACID:
Print mat B(3,1)
Print "WEED:
Print mat B(4,1)
Wait 
Print "SPEED:
Print mat B(5,1)
Print "DEXIES:
Print mat B(6,1)
Print "MONEY:
Print M
Wait 
Goto MENU
Label TRENCHCOAT
Print "COCAINE:
Print mat B(1,2)
Print "HEROIN:
Print mat B(2,2)
Print "ACID:
Print mat B(3,2)
Print "WEED:
Print mat B(4,2)
Wait 
Print "SPEED:
Print mat B(5,2)
Print "DEXIES:
Print mat B(6,2)
Print "FREE SPACE:
Print F
Wait 
Goto MENU
Label NOTENOUGH
Print "NOT ENOUGH SPACE
Wait 
Label BUY
Print "1) COCAINE
Print "2) HEROIN   3) ACID   4) WEED     5) SPEED  6) DEXIES
Print "WHAT TO BUY
Input C
If C<1Goto BUY
If C>6Goto BUY
Print "YOU CAN AFFORD
Print int (M/mat B(C,1))
Print "HOW MUCH
Input X
int X@sto@X
If X<0Goto BUY
If X>int (M/mat B(C,1))Goto BUY
If X>FGoto NOTENOUGH
ClrT
M-Xmat B(C,1)@sto@M
mat B(C,2)+X@sto@mat B(C,2)
Gosub CALCFREE
Goto MENU
Label SELL
Print "1) COCAINE
Print "2) HEROIN   3) ACID   4) WEED     5) SPEED  6) DEXIES
Print "WHAT TO SELL
Input C
If C<1Goto SELL
If C>6Goto SELL
Print "YOU HAVE
Print mat B(C,2)
Print "HOW MUCH
Input X
int X@sto@X
If X<0Goto SELL
If X>mat B(C,2)Goto SELL
M+Xmat B(C,1)@sto@M
mat B(C,2)-X@sto@mat B(C,2)
Gosub CALCFREE
Goto MENU
Label YOUREALREADY
Print "YOU'RE ALREADY THERE!
Wait 
Label GO
Print "1) SUICIDE  2) STAY
Print "3) BRONX    4) GHETTO
Print "5) CENTRAL PARK
Print "6) MANHATTEN
Print "7) BROOKLYN
Print "WHERE TO
Input C
int C@sto@C
If C<1Goto GO
If C>7Goto GO
If C=2Goto MENU
If C=PGoto YOUREALREADY
C@sto@P
If C=1Goto END
ClrT
Print "SUBWAY
Y+1@sto@Y
int (1.1D)@sto@D
int (1.06B)@sto@B
Wait 1
If Y=31Goto END
Goto NEWDAY
Label LOANBRONX
Print "THE LOAN SHARK ONLY   DEALS IN THE BRONX.
Wait 
Goto MENU
Label LOAN
If P@not_=@3Goto LOANBRONX
ClrT
Print "LOAN SHARK
Print "1) REPAY
Print "2) BORROW
Print "3) NEVER MIND
Print "CHOICE
Input C
If C<1Goto LOAN
If C>3Goto LOAN
If C=3Goto MENU
Label DISPLOAN
Print "DEBT:
Print D
Print "WALLET:
Print M
If C=2Goto BORROW
Print "REPAY HOW MUCH
Input X
int X@sto@X
If X<0Goto LOAN
If X>MGoto DISPLOAN
If X>DGoto DISPLOAN
D-X@sto@D
M-X@sto@M
Goto MENU
Label TOOMUCH
Print "YOU THINK HE'S CRAZY, MAN!
Wait 
Goto DISPLOAN
Label BORROW
Print "BORROW HOW MUCH
Input X
int X@sto@X
If X<0Goto LOAN
If X+D>50000Goto TOOMUCH
D+X@sto@D
M+X@sto@M
Goto MENU
Label BANKBRONX
Print "THE BANK IS IN THE    BRONX.
Wait 
Goto MENU
Label BANK
If P@not_=@3Goto BANKBRONX
ClrT
Print "1) VIEW ACCOUNT
Print "2) DEPOSIT
Print "3) WITHDRAW
Print "4) GOODBYE
Print "CHOICE
Input C
int C@sto@C
If C<1Goto BANK
If C>4Goto BANK
If C=4Goto MENU
Label DISPBANK
Print "ACCOUNT:
Print B
Print "WALLET:
Print M
Wait 
If C=1Goto BANK
If C=3Goto BANKDRAW
Print "DEPOSIT HOW MUCH
Input X
int X@sto@X
If X>MGoto DISPBANK
If X<0Goto DISPBANK
M-X@sto@M
B+X@sto@B
Goto BANK
Label BANKDRAW
Print "WITHDRAW HOW MUCH
Input X
int X@sto@X
If X>BGoto DISPBANK
If X<0Goto DISPBANK
B-X@sto@B
M+X@sto@M
Goto BANK
Label END
ClrT
Print "GAME OVER!
Print "----------
B-D+M@sto@O
(abs(O)+O)/2@sto@O
Print "SCORE (OUT OF 100):
int (@root@O/31.5)@sto@O
Print O
If O@<=@KGoto BYE
Print "YOU GOT A NEW HIGH    SCORE! WELL DONE!
O@sto@K
Label BYE
Wait 
ClrT
Print "THANKS FOR PLAYING!
Print "HAVE A NICE DAY!
End
Label CALCFREE
T-mat B(1,2)-mat B(2,2)-mat B(3,2)-mat B(4,2)-mat B(5,2)-mat B(6,2)@sto@F
Return
Label INSTRUC
Print "     DRUGWAR HELP
Print "---------------------
Print "THIS IS A GAME OF
Print "BUYING AND SELLING.
Print "YOUR GOAL IS TO PAY
Print "OFF YOUR DEBT TO THE
Print "LOAN SHARK AND THEN
Wait 
Print "MAKE AS MUCH MONEY AS
Print "POSSIBLE IN A ONE
Print "MONTH PERIOD. WATCH
Print "OUT FOR THE POLICE IF
Print "YOU DEAL TOO HEAVILY!
Wait 
Print "PRICES FOR DRUGS ARE:
Print "COCAINE:   16000-28000
Print "HEROIN:     5000-12000
Print "ACID:       1000- 4400
Print "WEED:        330-  750
Print "SPEED:        70-  220
Print "DEXIES:       10-   50
Wait 
Print "GENERALLY, ENTER THE
Print "NUMBER OF WHAT YOU
Print "WANT TO DO, BUT 1=YES
Print "2=NO. THE LAST NUMBER
Print "IN THE PRICES LIST IS
Print "YOUR WALLET. THE LAST
Print "NUMBER IN YOUR TRENCH-
Print "COAT IS FREE SPACE.
Wait 
ClrT
Goto NEWDAY